################################################
#This script extracts duration, medianF0,
#meanF0, StDev, minF0, maxF0 for each x and x_ip
#interval
#
#@jeanin
#created: 08/03/2016, last changed: 08/03/2016
################################################

clearinfo

file$ = "output.txt"
tier = 1

writeFileLine: file$, "file", tab$, "label", tab$, "duration", tab$, "meanF0", tab$, "medianF0", tab$, "StDevF0", tab$, "minF0", tab$, "maxF0"

Create Strings as file list: "fileList", "*.wav"

selectObject: "Strings fileList"
numberOfStrings = Get number of strings

for string to numberOfStrings
	selectObject: "Strings fileList"

	string$ = Get string: string
	Read from file: string$
	name$ = selected$ ("Sound")
	Read from file: name$ + ".TextGrid"

	selectObject: "Sound " + name$
	To Pitch: 0, 75, 500


	selectObject: "TextGrid " + name$

	numberOfIntervals = Get number of intervals: tier

	for n to numberOfIntervals
		selectObject: "TextGrid " + name$
		label$ = Get label of interval: tier, n

		if label$ = "<p>" or label$ = "<ips>"
			start = Get start point: tier, n
			end = Get end point: tier, n
			duration = (end-start)*1000

			selectObject: "Pitch " + name$
			meanF0 = Get mean: start, end, "Hertz"
			stDevF0 = Get standard deviation: start, end, "Hertz"
			minF0 = Get minimum: start, end, "Hertz", "Parabolic"
			maxF0 = Get maximum: start, end, "Hertz", "Parabolic"
			medianF0 = Get quantile: start, end, 0.5, "Hertz"

			appendFileLine: file$, name$, tab$, label$, tab$, duration, tab$, meanF0, tab$, medianF0, tab$, stDevF0, tab$, minF0, tab$, maxF0
		endif
	endfor

endfor




appendInfoLine: "Done."